Nous sommes toujours en quête de nouvelles idées pour améliorer la commande des trains et des accessoires. Dans les montages et articles précédents, nous avions beaucoup utilisé les modules Arduino associés à des modules radio. Il y a désormais de nouveaux modules qui intègrent les deux.
Nous réalisons des petits essais afin de savoir si cela est vraiment intéressant pour nos applications et quelles seraient les limites.
Le module que nous avons utilisé est le MKR WiFi 1010. Ce module est très compact et ressemble beaucoup aux autres modules Arduino. On trouve sa description complète sur le site officiel Arduino.
Vue du module avec une LED de test
Attention car les entrées ne supportent que du 3,3V. Il faut donc une carte d'adaptation (module dit "connector carrier)! Ceci rend le module tout de suite un peu plus encombrant mais rien d'irrémédiable.
Il y a 14 connecteurs 4 pins de type GROVE pour l'analogique et le digital. Cela permettrait de fiabiliser les connexions avec des modules externes (ex: relais) à condition d'avoir le même type de connecteur. N'ayant pas vu qu'il fallait un module d'adaptation, nous avons fait des essais avec une simple LED et une platine.
Un peu de code:
Ci-dessous le code (exemple disponible sur le Net par Tom Igoe) avec que vous pouvez copier dans votre éditeur Arduino. A noter qu'il y a aussi un fichier WiFiNINA.h qui contient les deux informations importantes que sont le SSID (identifiant de votre réseau) et le mot de passe.
Le principe est celui d'un client-serveur WEB qui utilise les services d'une librairie WiFiNINA qu'il faut bien sûr ajouter à votre bibliothèque dans l'IDE Arduino.
[code]
/*
WiFi Web Server LED Blink
A simple web server that lets you blink an LED via the web.
This sketch will print the IP address of your WiFi module (once connected)
to the Serial Monitor. From there, you can open that address in a web browser
to turn on and off the LED on pin 9.
If the IP address of your board is yourAddress:
http://yourAddress/H turns the LED on
http://yourAddress/L turns it off
This example is written for a network using WPA encryption. For
WEP or WPA, change the WiFi.begin() call accordingly.
Circuit:
* Board with NINA module (Arduino MKR WiFi 1010, MKR VIDOR 4000 and UNO WiFi Rev.2)
* LED attached to pin 9
created 25 Nov 2012 by Tom Igoe
*/
#include <SPI.h>
#include <WiFiNINA.h>
#include "arduino_secrets.h"
///////please enter your sensitive data in the Secret tab/arduino_secrets.h
char ssid[] = SECRET_SSID; // your network SSID (name)
char pass[] = SECRET_PASS; // your network password (use for WPA, or use as key for WEP)
int keyIndex = 0; // your network key index number (needed only for WEP)
int status = WL_IDLE_STATUS;
WiFiServer server(80);
void setup() {
Serial.begin(9600); // initialize serial communication
pinMode(9, OUTPUT); // set the LED pin mode
// check for the WiFi module:
if (WiFi.status() == WL_NO_MODULE) {
Serial.println("Communication with WiFi module failed!");
// don't continue
while (true);
}
String fv = WiFi.firmwareVersion();
if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
Serial.println("Please upgrade the firmware");
}
// attempt to connect to WiFi network:
while (status != WL_CONNECTED) {
Serial.print("Attempting to connect to Network named: ");
Serial.println(ssid); // print the network name (SSID);
// Connect to WPA/WPA2 network. Change this line if using open or WEP network:
status = WiFi.begin(ssid, pass);
// wait 10 seconds for connection:
delay(10000);
}
server.begin(); // start the web server on port 80
printWifiStatus(); // you're connected now, so print out the status
}
void loop() {
WiFiClient client = server.available(); // listen for incoming clients
if (client) { // if you get a client,
Serial.println("new client"); // print a message out the serial port
String currentLine = ""; // make a String to hold incoming data from the client
while (client.connected()) { // loop while the client's connected
if (client.available()) { // if there's bytes to read from the client,
char c = client.read(); // read a byte, then
Serial.write(c); // print it out the serial monitor
if (c == '\n') { // if the byte is a newline character
// if the current line is blank, you got two newline characters in a row.
// that's the end of the client HTTP request, so send a response:
if (currentLine.length() == 0) {
// HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
// and a content-type so the client knows what's coming, then a blank line:
client.println("HTTP/1.1 200 OK");
client.println("Content-type:text/html");
client.println();
// the content of the HTTP response follows the header:
client.print("Click <a href=\"/H\">here</a> turn the LED on pin 9 on<br>");
client.print("Click <a href=\"/L\">here</a> turn the LED on pin 9 off<br>");
// The HTTP response ends with another blank line:
client.println();
// break out of the while loop:
break;
} else { // if you got a newline, then clear currentLine:
currentLine = "";
}
} else if (c != '\r') { // if you got anything else but a carriage return character,
currentLine += c; // add it to the end of the currentLine
}
// Check to see if the client request was "GET /H" or "GET /L":
if (currentLine.endsWith("GET /H")) {
digitalWrite(9, HIGH); // GET /H turns the LED on
}
if (currentLine.endsWith("GET /L")) {
digitalWrite(9, LOW); // GET /L turns the LED off
}
}
}
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
void printWifiStatus() {
// print the SSID of the network you're attached to:
Serial.print("SSID: ");
Serial.println(WiFi.SSID());
// print your board's IP address:
IPAddress ip = WiFi.localIP();
Serial.print("IP Address: ");
Serial.println(ip);
// print the received signal strength:
long rssi = WiFi.RSSI();
Serial.print("signal strength (RSSI):");
Serial.print(rssi);
Serial.println(" dBm");
// print where to go in a browser:
Serial.print("To see this page in action, open a browser to http://");
Serial.println(ip);
}
[/code]
Traces et tests:
Lorsque vous avez téléchargé le code, démarrez le moniteur série. Lisez l'adresse qui est affichée (ici 192.168.1.113). C'est cette adresse qu'il vous faudra saisir dans le navigateur Internet de votre Smartphone.
Puis "cliquez" sur le texte "here" de la première ligne pour lancer la commande ON. La LED s'allume! On peut également voir les traces de la commande s'afficher dans la fenêtre du moniteur. Essayez maintenant la seconde ligne avec la commande OFF.
La portée radio est aussi bonne qu'avec nos premiers montages (Arduino Nano et NRF24L01).
L'interface sur le Smartphone est rustique mais on peut l'améliorer.
Vue de l'interface basique sur un Smartphone
C'est assez prometteur. Il reste à essayer avec la carte d'adaptation et d'autres modules (relais, ampli) pour refaire, par exemple, un module de commande sans fil des aiguilles.
A suivre.
